1 Strings and Characters

A string in Emacs Lisp is an array that contains an ordered sequence of characters. Strings are used as names of symbols, buffers, and files, to send messages to users, to hold text being copied between buffers, and for many other purposes. Because strings are so important, many functions are provided expressly for manipulating them. Emacs Lisp programs use strings more often than individual characters.

@xref{Strings of Events}, for special considerations when using strings of keyboard character events.

1.1 Introduction to Strings and Characters

Strings in Emacs Lisp are arrays that contain an ordered sequence of characters. Characters are represented in Emacs Lisp as integers; whether an integer was intended as a character or not is determined only by how it is used. Thus, strings really contain integers.

The length of a string (like any array) is fixed and independent of the string contents, and cannot be altered. Strings in Lisp are not terminated by a distinguished character code. (By contrast, strings in C are terminated by a character with ASCII code 0.) This means that any character, including the null character (ASCII code 0), is a valid element of a string.

Since strings are considered arrays, you can operate on them with the general array functions. (@xref{Sequences Arrays Vectors}.) For example, you can access or change individual characters in a string using the functions aref and aset (@pxref{Array Functions}).

Each character in a string is stored in a single byte. Therefore, numbers not in the range 0 to 255 are truncated when stored into a string. This means that a string takes up much less memory than a vector of the same length.

Sometimes key sequences are represented as strings. When a string is a key sequence, string elements in the range 128 to 255 represent meta characters (which are extremely large integers) rather than keyboard events in the range 128 to 255.

Strings cannot hold characters that have the hyper, super or alt modifiers; they can hold ASCII control characters, but no others. They do not distinguish case in ASCII control characters. @xref{Character Type}, for more information about representation of meta and other modifiers for keyboard input characters.

Like a buffer, a string can contain text properties for the characters in it, as well as the characters themselves. @xref{Text Properties}.

@xref{Text}, for information about functions that display strings or copy them into buffers. @xref{Character Type}, and @ref{String Type}, for information about the syntax of characters and strings.

1.2 The Predicates for Strings

For more information about general sequence and array predicates, see @ref{Sequences Arrays Vectors}, and @ref{Arrays}.

Function: stringp object

This function returns t if object is a string, nil otherwise.

Function: char-or-string-p object

This function returns t if object is a string or a character (i.e., an integer), nil otherwise.

1.3 Creating Strings

The following functions create strings, either from scratch, or by putting strings together, or by taking them apart.

Function: make-string count character

This function returns a string made up of count repetitions of character. If count is negative, an error is signaled.

(make-string 5 ?x)
     ⇒ "xxxxx"
(make-string 0 ?x)
     ⇒ ""

Other functions to compare with this one include char-to-string (see section Conversion of Characters and Strings), make-vector (@pxref{Vectors}), and make-list (@pxref{Building Lists}).

Function: substring string start &optional end

This function returns a new string which consists of those characters from string in the range from (and including) the character at the index start up to (but excluding) the character at the index end. The first character is at index zero.

(substring "abcdefg" 0 3)
     ⇒ "abc"

Here the index for ‘a’ is 0, the index for ‘b’ is 1, and the index for ‘c’ is 2. Thus, three letters, ‘abc’, are copied from the full string. The index 3 marks the character position up to which the substring is copied. The character whose index is 3 is actually the fourth character in the string.

A negative number counts from the end of the string, so that -1 signifies the index of the last character of the string. For example:

(substring "abcdefg" -3 -1)
     ⇒ "ef"

In this example, the index for ‘e’ is -3, the index for ‘f’ is -2, and the index for ‘g’ is -1. Therefore, ‘e’ and ‘f’ are included, and ‘g’ is excluded.

When nil is used as an index, it falls after the last character in the string. Thus:

(substring "abcdefg" -3 nil)
     ⇒ "efg"

Omitting the argument end is equivalent to specifying nil. It follows that (substring string 0) returns a copy of all of string.

(substring "abcdefg" 0)
     ⇒ "abcdefg"

But we recommend copy-sequence for this purpose (@pxref{Sequence Functions}).

A wrong-type-argument error is signaled if either start or end are non-integers. An args-out-of-range error is signaled if start indicates a character following end, or if either integer is out of range for string.

Contrast this function with buffer-substring (@pxref{Buffer Contents}), which returns a string containing a portion of the text in the current buffer. The beginning of a string is at index 0, but the beginning of a buffer is at index 1.

Function: concat &rest sequences

This function returns a new string consisting of the characters in the arguments passed to it. The arguments may be strings, lists of numbers, or vectors of numbers; they are not themselves changed. If no arguments are passed to concat, it returns an empty string.

(concat "abc" "-def")
     ⇒ "abc-def"
(concat "abc" (list 120 (+ 256 121)) [122])
     ⇒ "abcxyz"
(concat "The " "quick brown " "fox.")
     ⇒ "The quick brown fox."
(concat)
     ⇒ ""

The second example above shows how characters stored in strings are taken modulo 256. In other words, each character in the string is stored in one byte.

The concat function always constructs a new string that is not eq to any existing string.

When an argument is an integer (not a sequence of integers), it is converted to a string of digits making up the decimal printed representation of the integer. This special case exists for compatibility with Mocklisp, and we don’t recommend you take advantage of it. If you want to convert an integer in this way, use format (see section Formatting Strings) or int-to-string (see section Conversion of Characters and Strings).

(concat 137)
     ⇒ "137"
(concat 54 321)
     ⇒ "54321"

For information about other concatenation functions, see the description of mapconcat in @ref{Mapping Functions}, vconcat in @ref{Vectors}, and append in @ref{Building Lists}.

1.4 Comparison of Characters and Strings

Function: char-equal character1 character2

This function returns t if the arguments represent the same character, nil otherwise. This function ignores differences in case if case-fold-search is non-nil.

(char-equal ?x ?x)
     ⇒ t
(char-to-string (+ 256 ?x))
     ⇒ "x"
(char-equal ?x  (+ 256 ?x))
     ⇒ t

Function: string= string1 string2

This function returns t if the characters of the two strings match exactly; case is significant.

(string= "abc" "abc")
     ⇒ t
(string= "abc" "ABC")
     ⇒ nil
(string= "ab" "ABC")
     ⇒ nil

Function: string-equal string1 string2

string-equal is another name for string=.

Function: string< string1 string2

This function compares two strings a character at a time. First it scans both the strings at once to find the first pair of corresponding characters that do not match. If the lesser character of those two is the character from string1, then string1 is less, and this function returns t. If the lesser character is the one from string2, then string1 is greater, and this function returns nil. If the two strings match entirely, the value is nil.

Pairs of characters are compared by their ASCII codes. Keep in mind that lower case letters have higher numeric values in the ASCII character set than their upper case counterparts; numbers and many punctuation characters have a lower numeric value than upper case letters.

(string< "abc" "abd")
     ⇒ t
(string< "abd" "abc")
     ⇒ nil
(string< "123" "abc")
     ⇒ t

When the strings have different lengths, and they match up to the length of string1, then the result is t. If they match up to the length of string2, the result is nil. A string without any characters in it is the smallest possible string.

(string< "" "abc")
     ⇒ t
(string< "ab" "abc")
     ⇒ t
(string< "abc" "")
     ⇒ nil
(string< "abc" "ab")
     ⇒ nil
(string< "" "")
     ⇒ nil                   

Function: string-lessp string1 string2

string-lessp is another name for string<.

See compare-buffer-substrings in @ref{Comparing Text}, for a way to compare text in buffers.

1.5 Conversion of Characters and Strings

Characters and strings may be converted into each other and into integers. format and prin1-to-string (@pxref{Output Functions}) may also be used to convert Lisp objects into strings. read-from-string (@pxref{Input Functions}) may be used to “convert” a string representation of a Lisp object into an object.

@xref{Documentation}, for a description of functions which return a string representing the Emacs standard notation of the argument character (single-key-description and text-char-description). These functions are used primarily for printing help messages.

Function: char-to-string character

This function returns a new string with a length of one character. The value of character, modulo 256, is used to initialize the element of the string.

This function is similar to make-string with an integer argument of 1. (See section Creating Strings.) This conversion can also be done with format using the ‘%c’ format specification. (See section Formatting Strings.)

(char-to-string ?x)
     ⇒ "x"
(char-to-string (+ 256 ?x))
     ⇒ "x"
(make-string 1 ?x)
     ⇒ "x"

Function: string-to-char string

This function returns the first character in string. If the string is empty, the function returns 0. The value is also 0 when the first character of string is the null character, ASCII code 0.

(string-to-char "ABC")
     ⇒ 65
(string-to-char "xyz")
     ⇒ 120
(string-to-char "")
     ⇒ 0
(string-to-char "\000")
     ⇒ 0

This function may be eliminated in the future if it does not seem useful enough to retain.

Function: number-to-string number

Function: int-to-string number

This function returns a string consisting of the printed representation of number, which may be an integer or a floating point number. The value starts with a sign if the argument is negative.

(int-to-string 256)
     ⇒ "256"
(int-to-string -23)
     ⇒ "-23"
(int-to-string -23.5)
     ⇒ "-23.5"

See also the function format in Formatting Strings.

Function: string-to-number string

Function: string-to-int string

This function returns the integer value of the characters in string, read as a number in base ten. It skips spaces at the beginning of string, then reads as much of string as it can interpret as a number. (On some systems it ignores other whitespace at the beginning, not just spaces.) If the first character after the ignored whitespace is not a digit or a minus sign, this function returns 0.

(string-to-number "256")
     ⇒ 256
(string-to-number "25 is a perfect square.")
     ⇒ 25
(string-to-number "X256")
     ⇒ 0
(string-to-number "-4.5")
     ⇒ -4.5

1.6 Formatting Strings

Formatting means constructing a string by substitution of computed values at various places in a constant string. This string controls how the other values are printed as well as where they appear; it is called a format string.

Formatting is often useful for computing messages to be displayed. In fact, the functions message and error provide the same formatting feature described here; they differ from format only in how they use the result of formatting.

Function: format string &rest objects

This function returns a new string that is made by copying string and then replacing any format specification in the copy with encodings of the corresponding objects. The arguments objects are the computed values to be formatted.

A format specification is a sequence of characters beginning with a ‘%’. Thus, if there is a ‘%d’ in string, the format function replaces it with the printed representation of one of the values to be formatted (one of the arguments objects). For example:

(format "The value of fill-column is %d." fill-column)
     ⇒ "The value of fill-column is 72."

If string contains more than one format specification, the format specifications are matched with successive values from objects. Thus, the first format specification in string is matched with the first such value, the second format specification is matched with the second such value, and so on. Any extra format specifications (those for which there are no corresponding values) cause unpredictable behavior. Any extra values to be formatted will be ignored.

Certain format specifications require values of particular types. However, no error is signaled if the value actually supplied fails to have the expected type. Instead, the output is likely to be meaningless.

Here is a table of the characters that can follow ‘%’ to make up a format specification:

‘s’

Replace the specification with the printed representation of the object, made without quoting. Thus, strings are represented by their contents alone, with no ‘"’ characters, and symbols appear without ‘\’ characters.

If there is no corresponding object, the empty string is used.

‘S’

Replace the specification with the printed representation of the object, made with quoting. Thus, strings are enclosed in ‘"’ characters, and ‘\’ characters appear where necessary before special characters.

If there is no corresponding object, the empty string is used.

‘o’

Replace the specification with the base-eight representation of an integer.

‘d’

Replace the specification with the base-ten representation of an integer.

‘x’

Replace the specification with the base-sixteen representation of an integer.

‘c’

Replace the specification with the character which is the value given.

‘e’

Replace the specification with the exponential notation for a floating point number.

‘f’

Replace the specification with the decimal-point notation for a floating point number.

‘g’

Replace the specification with notation for a floating point number, using either exponential notation or decimal-point notation whichever is shorter.

‘%’

A single ‘%’ is placed in the string. This format specification is unusual in that it does not use a value. For example, (format "%% %d" 30) returns "% 30".

Any other format character results in an ‘Invalid format operation’ error.

Here are several examples:

(format "The name of this buffer is %s." (buffer-name))
     ⇒ "The name of this buffer is strings.texi."

(format "The buffer object prints as %s." (current-buffer))
     ⇒ "The buffer object prints as #<buffer strings.texi>."

(format "The octal value of 18 is %o, 
         and the hex value is %x." 18 18)
     ⇒ "The octal value of 18 is 22, 
         and the hex value is 12."

All the specification characters allow an optional numeric prefix between the ‘%’ and the character. The optional numeric prefix defines the minimum width for the object. If the printed representation of the object contains fewer characters than this, then it is padded. The padding is on the left if the prefix is positive (or starts with zero) and on the right if the prefix is negative. The padding character is normally a space, but if the numeric prefix starts with a zero, zeros are used for padding.

(format "%06d will be padded on the left with zeros" 123)
     ⇒ "000123 will be padded on the left with zeros"

(format "%-6d will be padded on the right" 123)
     ⇒ "123    will be padded on the right"

format never truncates an object’s printed representation, no matter what width you specify. Thus, you can use a numeric prefix to specify a minimum spacing between columns with no risk of losing information.

In the following three examples, ‘%7s’ specifies a minimum width of 7. In the first case, the string inserted in place of ‘%7s’ has only 3 letters, so 4 blank spaces are inserted for padding. In the second case, the string "specification" is 13 letters wide but is not truncated. In the third case, the padding is on the right.

(format "The word `%7s' actually has %d letters in it." "foo" 
        (length "foo"))
     ⇒ "The word `    foo' actually has 3 letters in it."  

(format "The word `%7s' actually has %d letters in it."
        "specification" 
        (length "specification")) 
     ⇒ "The word `specification' actually has 13 letters in it."  

(format "The word `%-7s' actually has %d letters in it." "foo" 
        (length "foo"))
     ⇒ "The word `foo    ' actually has 3 letters in it."  

1.7 Character Case

The character case functions change the case of single characters or of the contents of strings. The functions convert only alphabetic characters (the letters ‘A’ through ‘Z’ and ‘a’ through ‘z’); other characters are not altered. The functions do not modify the strings that are passed to them as arguments.

The examples below use the characters ‘X’ and ‘x’ which have ASCII codes 88 and 120 respectively.

Function: downcase string-or-char

This function converts a character or a string to lower case.

When the argument to downcase is a string, the function creates and returns a new string in which each letter in the argument that is upper case is converted to lower case. When the argument to downcase is a character, downcase returns the corresponding lower case character. This value is an integer. If the original character is lower case, or is not a letter, then the value equals the original character.

(downcase "The cat in the hat")
     ⇒ "the cat in the hat"

(downcase ?X)
     ⇒ 120

Function: upcase string-or-char

This function converts a character or a string to upper case.

When the argument to upcase is a string, the function creates and returns a new string in which each letter in the argument that is lower case is converted to upper case.

When the argument to upcase is a character, upcase returns the corresponding upper case character. This value is an integer. If the original character is upper case, or is not a letter, then the value equals the original character.

(upcase "The cat in the hat")
     ⇒ "THE CAT IN THE HAT"

(upcase ?x)
     ⇒ 88

Function: capitalize string-or-char

This function capitalizes strings or characters. If string-or-char is a string, the function creates and returns a new string, whose contents are a copy of string-or-char in which each word has been capitalized. This means that the first character of each word is converted to upper case, and the rest are converted to lower case.

The definition of a word is any sequence of consecutive characters that are assigned to the word constituent category in the current syntax table (@xref{Syntax Class Table}).

When the argument to capitalize is a character, capitalize has the same result as upcase.

(capitalize "The cat in the hat")
     ⇒ "The Cat In The Hat"

(capitalize "THE 77TH-HATTED CAT")
     ⇒ "The 77th-Hatted Cat"

(capitalize ?x)
     ⇒ 88

1.8 The Case Table

You can customize case conversion by installing a special case table. A case table specifies the mapping between upper case and lower case letters. It affects both the string and character case conversion functions (see the previous section) and those that apply to text in the buffer (@pxref{Case Changes}). Use case table if you are using a language which has letters that are not the standard ASCII letters.

A case table is a list of this form:

(downcase upcase canonicalize equivalences)

where each element is either nil or a string of length 256. The element downcase says how to map each character to its lower-case equivalent. The element upcase maps each character to its upper-case equivalent. If lower and upper case characters are in one-to-one correspondence, use nil for upcase; then Emacs deduces the upcase table from downcase.

For some languages, upper and lower case letters are not in one-to-one correspondence. There may be two different lower case letters with the same upper case equivalent. In these cases, you need to specify the maps for both directions.

The element canonicalize maps each character to a canonical equivalent; any two characters that are related by case-conversion have the same canonical equivalent character.

The element equivalences is a map that cyclicly permutes each equivalence class (of characters with the same canonical equivalent). (For ordinary ASCII, this would map ‘a’ into ‘A’ and ‘A’ into ‘a’, and likewise for each set of equivalent characters.)

You can provide nil for both canonicalize and equivalences, in which case both are deduced from downcase and upcase. Normally, that’s what you should do, when you construct a case table. But when you look at the case table that’s in use, you will find non-nil values for those components.

Each buffer has a case table. Emacs also has a standard case table which is copied into each buffer when you create the buffer. (Changing the standard case table doesn’t affect any existing buffers.)

Here are the functions for working with case tables:

Function: case-table-p object

This predicate returns non-nil if object is a valid case table.

Function: set-standard-case-table table

This function makes table the standard case table, so that it will apply to any buffers created subsequently.

Function: standard-case-table

This returns the standard case table.

Function: current-case-table

This function returns the current buffer’s case table.

Function: set-case-table table

This sets the current buffer’s case table to table.

The following three functions are convenient subroutines for packages that define non-ASCII character sets. They modify a string downcase-table provided as an argument; this should be a string to be used as the downcase part of a case table. They also modify two syntax tables, the standard syntax table and the Text mode syntax table. (@xref{Syntax Tables}.)

Function: set-case-syntax-pair uc lc downcase-table

This function specifies a pair of corresponding letters, one upper case and one lower case.

Function: set-case-syntax-delims l r downcase-table

This function makes characters l and r a matching pair of case-invariant delimiters.

Function: set-case-syntax char syntax downcase-table

This function makes char case-invariant, with syntax syntax.

Command: describe-buffer-case-table

This command displays a description of the contents of the current buffer’s case table.

You can load the library ‘iso-syntax’ to set up the syntax and case table for the 256 bit ISO Latin 1 character set.

About This Document

This document was generated on January 16, 2023 using texi2html 5.0.

The buttons in the navigation panels have the following meaning:

where the Example assumes that the current position is at Subsubsection One-Two-Three of a document of the following structure:

• 1. Section One
  • 1.1 Subsection One-One
    • ...
  • 1.2 Subsection One-Two
    • 1.2.1 Subsubsection One-Two-One
    • 1.2.2 Subsubsection One-Two-Two
    • 1.2.3 Subsubsection One-Two-Three     <== Current Position
    • 1.2.4 Subsubsection One-Two-Four
  • 1.3 Subsection One-Three
    • ...
  • 1.4 Subsection One-Four

This document was generated on January 16, 2023 using texi2html 5.0.